2ο ΓΕΛ Γέρακα - Λύσεις Πανελλαδικών ΑΕΠΠ

e-ΜΑΘΗΜΑΤΑ
Ανάπτυξη Εφαρμογών σε Προγραμματιστικό περιβάλλον
Λύσεις ασκήσεων Πανελλαδικών Εξετάσεων

!ΕΠΑΝΑΛΗΠΤΙΚΕΣ ΠΑΝΕΛΛΑΔΙΚΕΣ ΕΞΕΤΑΣΕΙΣ

!ΗΜΕΡΗΣΙΩΝ & ΕΣΠΕΡΙΝΩΝ ΓΕΝΙΚΩΝ ΛΥΚΕΙΩΝ

!ΤΕΤΑΡΤΗ 11 ΣΕΠΤΕΜΒΡΙΟΥ 2024

!

!ΘΕΜΑ Δ

!

!

!

 
ΠΡΟΓΡΑΜΜΑ ΘΕΜΑ_Δ_2024_ΕΠΑΝ

!ΘΕΜΑ Δ

!Για την εξυπηρέτηση πελατών μιας τράπεζας κατά τη διάρκεια μιας ημέρας

!χρησιμοποιείται ηλεκτρονικό σύστημα, το οποίο υλοποιείται με μια ουρά 250

!θέσεων. Κάθε φορά που εισέρχεται νέος πελάτης, δημιουργείται από το

!ηλεκτρονικό σύστημα ένας αύξων αριθμός που αντιστοιχεί στη σειρά εισόδου του

!πελάτη στην τράπεζα. Ο 1ος πελάτης έχει τον αύξοντα αριθμό 1, ο 2ος πελάτης

!τον αύξοντα αριθμό 2 κ.ο.κ. Να γραφεί πρόγραμμα σε ΓΛΩΣΣΑ, το οποίο:

!Δ1. α) Να περιλαμβάνει κατάλληλο τμήμα δηλώσεων (μονάδες 2).

!β) Να εμφανίζει επαναληπτικά το παρακάτω μενού επιλογών και να διαβάζει,

!χωρίς έλεγχο εγκυρότητας, την επιλογή 1 ή 2 ή 3.

!1. Εισαγωγή πελάτη

!2. Εξαγωγή πελάτη

!3. Τερματισμός

!Δώσε επιλογή: (μονάδες 2)

!Μονάδες 4

!Δ2. Με την επιλογή 1 και εφόσον η ουρά δεν είναι γεμάτη, να εισάγει τον αύξοντα

!αριθμό του πελάτη στην ουρά. Στην περίπτωση που η ουρά είναι γεμάτη, να

!εμφανίζει κατάλληλο μήνυμα και να μην υλοποιεί τη διαδικασία εισαγωγής.

!Μονάδες 7

!Δ3. Με την επιλογή 2, να πραγματοποιεί την εξαγωγή του πελάτη από την ουρά

!και να εμφανίζει τον αύξοντα αριθμό του. Στην περίπτωση που η ουρά είναι

!άδεια, να εμφανίζει κατάλληλο μήνυμα και να μην υλοποιεί τη διαδικασία

!εξαγωγής.

!Μονάδες 7

!Δ4. Με την επιλογή 3, να τερματίζεται η επαναληπτική διαδικασία και να

!εμφανίζει το πλήθος των πελατών που εξυπηρετήθηκαν (Εξαγωγή πελάτη)

!(μονάδες 3) καθώς και τον μέγιστο αριθμό πελατών που περίμεναν κάποια

!στιγμή στην ουρά (μονάδες 4).

!Μονάδες 7

!Σημείωση: Να θεωρήσετε ότι στην αρχή της ημέρας η ουρά είναι άδεια και ότι

!στην περίπτωση που επιλεχθεί η ενέργεια 3 (Τερματισμός) οι πελάτες που έχουν

!απομείνει στην ουρά της τράπεζας δεν θα εξυπηρετηθούν.



ΣΤΑΘΕΡΕΣ

  MAX = 250



ΜΕΤΑΒΛΗΤΕΣ

  ΧΑΡΑΚΤΗΡΕΣ: απάντηση

  ΑΚΕΡΑΙΕΣ: f, r, i, k

  ΑΚΕΡΑΙΕΣ: ΟΥΡΑ[MAX], αριθμός_πελάτη, πλήθος_εξυπηρετήθηκαν, μέγιστο_σε_αναμονή



ΑΡΧΗ

! αρχικοποίηση δεικτών

  f <- 0

  r <- 0



  αριθμός_πελάτη <- 0

  πλήθος_εξυπηρετήθηκαν <- 0

  μέγιστο_σε_αναμονή <- 0



  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ



!   Μενού επιλογών

    ΓΡΑΨΕ '1. Εισαγωγή πελάτη'

    ΓΡΑΨΕ '2. Εξαγωγή πελάτη'

    ΓΡΑΨΕ '3. Τερματισμός'

    ΓΡΑΨΕ 'Δώστε επιλογή: '

    ΔΙΑΒΑΣΕ απάντηση



    ΑΝ απάντηση = '1' ΤΟΤΕ

!Δ2. Με την επιλογή 1 και εφόσον η ουρά δεν είναι γεμάτη, να εισάγει τον αύξοντα

!αριθμό του πελάτη στην ουρά. Στην περίπτωση που η ουρά είναι γεμάτη, να

!εμφανίζει κατάλληλο μήνυμα και να μην υλοποιεί τη διαδικασία εισαγωγής.



      ΑΝ r = MAX ΤΟΤΕ

!         έλεγχος υπερχείλισης

        ΓΡΑΨΕ 'Γεμάτη ουρά'

      ΑΛΛΙΩΣ



        ΑΝ r = 0 ΚΑΙ f = 0 ΤΟΤΕ

!           αν ήταν το στοιχείο εισάγεται σε κενή ουρά

!           θα είναι ταυτόχρονα και τελευταίο (στην πρώτη θέση)

          r <- 1

          f <- 1

        ΑΛΛΙΩΣ

!           στη γενική περίπτωση το νέο στοιχείο εισάγεται στο τέλος της ουράς

          r <- r + 1

        ΤΕΛΟΣ_ΑΝ



        αριθμός_πελάτη <- αριθμός_πελάτη + 1

        ΟΥΡΑ[r] <- αριθμός_πελάτη



        ΑΝ μέγιστο_σε_αναμονή < r - f + 1 ΤΟΤΕ

          μέγιστο_σε_αναμονή <- r - f + 1

        ΤΕΛΟΣ_ΑΝ

      ΤΕΛΟΣ_ΑΝ





    ΑΛΛΙΩΣ_ΑΝ απάντηση = '2' ΤΟΤΕ

!Δ3. Με την επιλογή 2, να πραγματοποιεί την εξαγωγή του πελάτη από την ουρά

!και να εμφανίζει τον αύξοντα αριθμό του. Στην περίπτωση που η ουρά είναι

!άδεια, να εμφανίζει κατάλληλο μήνυμα και να μην υλοποιεί τη διαδικασία

!εξαγωγής.

      ΑΝ f = 0 ΤΟΤΕ

!         έλεγχος για κενή ουρά

        ΓΡΑΨΕ 'Αδεια ουρά'

      ΑΛΛΙΩΣ

        ΓΡΑΨΕ 'Eξαγωγή : ', ΟΥΡΑ[f] 

        ΟΥΡΑ[f] <- 0

        ΑΝ f = r ΤΟΤΕ

          f <- 0

          r <- 0

        ΑΛΛΙΩΣ

          f <- f + 1

        ΤΕΛΟΣ_ΑΝ



        πλήθος_εξυπηρετήθηκαν <- πλήθος_εξυπηρετήθηκαν + 1

      ΤΕΛΟΣ_ΑΝ



    ΑΛΛΙΩΣ_ΑΝ απάντηση = '3' ΤΟΤΕ

!Δ4. Με την επιλογή 3, να τερματίζεται η επαναληπτική διαδικασία και να

!εμφανίζει το πλήθος των πελατών που εξυπηρετήθηκαν (Εξαγωγή πελάτη)

!(μονάδες 3) καθώς και τον μέγιστο αριθμό πελατών που περίμεναν κάποια

!στιγμή στην ουρά (μονάδες 4).



      ΓΡΑΨΕ 'Πλήθος των πελατών που εξυπηρετήθηκαν : ', πλήθος_εξυπηρετήθηκαν

      ΓΡΑΨΕ 'Μέγιστος αριθμός πελατών που περίμεναν κάποια στιγμή : ', μέγιστο_σε_αναμονή





    ΑΛΛΙΩΣ

      ΓΡΑΨΕ 'Λάθος επιλογή'



    ΤΕΛΟΣ_ΑΝ

  ΜΕΧΡΙΣ_ΟΤΟΥ απάντηση = '3'

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ