ΠΡΟΓΡΑΜΜΑ ΔΑΝΕΙΣΤΙΚΗ_ΒΙΒΛΙΟΘΗΚΗ
! Βραδινά 2010 Θ4
! Σε μια δημοτική δανειστική βιβλιοθήκη υπάρχουν 158 μέλη που δανείζονται βιβλία.
! Να γραφεί αλγόριθμος που:
!Δ1. α. Για κάθε μέλος διαβάζει το επώνυμο και το φύλο του (Α=άνδρας,
!       Γ=γυναίκα) και τα αποθηκεύει στους πίνακες ΜΕΛΗ και ΦΥΛΟ, αντίστοιχα.
!       Να γίνεται έλεγχος εγκυρότητας εισαγωγής του φύλου. (μονάδες 4)
!    β. Για κάθε μήνα ενός έτους διαβάζει το πλήθος των βιβλίων που
!       δανείστηκε κάθε μέλος και το αποθηκεύει στον πίνακα δύο
!       διαστάσεων ΒΙΒΛΙΑ. (μονάδες 2)
!
!Δ2. Για κάθε μέλος υπολογίζει το συνολικό αριθμό των βιβλίων που
!    δανείστηκε στο έτος και το αποθηκεύει στον πίνακα SUM. Μονάδες 2
!
!Δ3. α. Υπολογίζει το συνολικό αριθμό των βιβλίων που δανείστηκαν
!       οι άνδρες. (μονάδες 2)
!    β. Υπολογίζει το συνολικό αριθμό των βιβλίων που δανείστηκαν
!       οι γυναίκες. (μονάδες 2)
!    γ. Εμφανίζει κατάλληλο μήνυμα που δείχνει αν οι άνδρες ή οι
!       γυναίκες έχουν δανειστεί τα περισσότερα βιβλία. Σε περίπτωση
!      ίσων συνολικών αριθμών βιβλίων να εμφανίζει το μήνυμα
!      “ΙΣΟΣ ΑΡΙΘΜΟΣ ΒΙΒΛΙΩΝ”.(μονάδες 2)
!
!Δ4. Να διαβάζει ένα επώνυμο και χρησιμοποιώντας τη σειριακή αναζήτηση,
!    σε περίπτωση που το επώνυμο είναι αποθηκευμένο στον πίνακα ΜΕΛΗ,
!    να εμφανίζει το σύνολο των βιβλίων που δανείστηκε στη διάρκεια του
!    έτους. Σε περίπτωση που το επώνυμο δεν είναι αποθηκευμένο στον
!    πίνακα να εμφανίζει το μήνυμα “ΤΟ ΕΠΩΝΥΜΟ ΑΥΤΟ ΔΕΝ ΥΠΑΡΧΕΙ”.
!    Μονάδες 6
!Σημείωση: Δεν απαιτείται κανένας άλλος έλεγχος εγκυρότητας εισαγωγής.
!Δεν υπάρχει συνωνυμία επωνύμων.

ΣΤΑΘΕΡΕΣ
  ΠΛΗΘΟΣ = 158                 ! Αλλάξτε το σε 5 αν το τρέξετε στην Αλγοριθμική 

ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: i, j, ΒΙΒΛΙΑ[ΠΛΗΘΟΣ, 12], SUM[ΠΛΗΘΟΣ], σύνολο_βιβλίων_ανδρών, σύνολο_βιβλίων_γυναικών
  ΧΑΡΑΚΤΗΡΕΣ: ΜΕΛΗ[ΠΛΗΘΟΣ], ΦΥΛΟ[ΠΛΗΘΟΣ], επώνυμο
  ΛΟΓΙΚΕΣ: βρέθηκε

ΑΡΧΗ
!Δ1. α. Για κάθε μέλος διαβάζει το επώνυμο και το φύλο του Α=άνδρας,
!       Γ=γυναίκα) και τα αποθηκεύει στους πίνακες ΜΕΛΗ και ΦΥΛΟ, αντίστοιχα.
!       Να γίνεται έλεγχος εγκυρότητας εισαγωγής του φύλου. (μονάδες 4)
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ ΠΛΗΘΟΣ
    ΓΡΑΨΕ 'Δώσε επώνυμο ', i, 'ου μέλους: '
    ΔΙΑΒΑΣΕ ΜΕΛΗ[i] 
    
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΓΡΑΨΕ 'Δώσε φύλο (Α=άνδρας, Γ=γυναίκα) : '
      ΔΙΑΒΑΣΕ ΦΥΛΟ[i] 
      ΑΝ (ΦΥΛΟ[i] <> 'Α') ΚΑΙ (ΦΥΛΟ[i] <> 'Γ') ΤΟΤΕ
        ΓΡΑΨΕ 'Λάθος τιμή. Δώστε πάλι Α ή Γ'
      ΤΕΛΟΣ_ΑΝ
    ΜΕΧΡΙΣ_ΟΤΟΥ (ΦΥΛΟ[i] = 'Α') Η (ΦΥΛΟ[i] = 'Γ') 
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ


!    β. Για κάθε μήνα ενός έτους διαβάζει το πλήθος των βιβλίων που
!       δανείστηκε κάθε μέλος και το αποθηκεύει στον πίνακα δύο
!       διαστάσεων ΒΙΒΛΙΑ. (μονάδες 2)
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ ΠΛΗΘΟΣ
    ΓΡΑΨΕ i, 'ο μέλος'
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 12
      ΓΡΑΨΕ 'Δώσε πλήθος των βιβλίων για τον μήνα ', j, ': '
      ΔΙΑΒΑΣΕ ΒΙΒΛΙΑ[i, j] 
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ


! --------------------------------------------------------------

!Δ2. Για κάθε μέλος υπολογίζει το συνολικό αριθμό των βιβλίων που
!    δανείστηκε στο έτος και το αποθηκεύει στον πίνακα SUM. Μονάδες 2

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ ΠΛΗΘΟΣ
    SUM[i] <- 0
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 12
      SUM[i] <- SUM[i] + ΒΙΒΛΙΑ[i, j] 
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  
! Εναλλακτικά Δ1 και Δ2 πιο σύντομα
!  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ ΠΛΗΘΟΣ
!    SUM [i] <- 0
!    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 12
!      ΔΙΑΒΑΣΕ ΒΙΒΛΙΑ[i, j]
!       SUM [i] <-  SUM [i] + ΒΙΒΛΙΑ[i, j]
!    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
!  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

! --------------------------------------------------------------

!Δ3. α. Υπολογίζει το συνολικό αριθμό των βιβλίων που δανείστηκαν
!       οι άνδρες. (μονάδες 2)
!    β. Υπολογίζει το συνολικό αριθμό των βιβλίων που δανείστηκαν
!       οι γυναίκες. (μονάδες 2)
!    γ. Εμφανίζει κατάλληλο μήνυμα που δείχνει αν οι άνδρες ή οι
!       γυναίκες έχουν δανειστεί τα περισσότερα βιβλία. Σε περίπτωση
!      ίσων συνολικών αριθμών βιβλίων να εμφανίζει το μήνυμα
!      “ΙΣΟΣ ΑΡΙΘΜΟΣ ΒΙΒΛΙΩΝ”.(μονάδες 2)
  σύνολο_βιβλίων_ανδρών <- 0
  σύνολο_βιβλίων_γυναικών <- 0
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ ΠΛΗΘΟΣ
    ΑΝ (ΦΥΛΟ[i] = 'Α') ΤΟΤΕ
      σύνολο_βιβλίων_ανδρών <- σύνολο_βιβλίων_ανδρών + SUM[i] 
    ΑΛΛΙΩΣ
      σύνολο_βιβλίων_γυναικών <- σύνολο_βιβλίων_γυναικών + SUM[i] 
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  
  ΑΝ σύνολο_βιβλίων_ανδρών > σύνολο_βιβλίων_γυναικών ΤΟΤΕ
    ΓΡΑΨΕ 'Οι άνδρες έχουν δανειστεί τα περισσότερα βιβλία'
  ΑΛΛΙΩΣ_ΑΝ σύνολο_βιβλίων_ανδρών < σύνολο_βιβλίων_γυναικών ΤΟΤΕ
    ΓΡΑΨΕ 'Οι γυναίκες έχουν δανειστεί τα περισσότερα βιβλία'
  ΑΛΛΙΩΣ
    ΓΡΑΨΕ 'ΙΣΟΣ ΑΡΙΘΜΟΣ ΒΙΒΛΙΩΝ'
  ΤΕΛΟΣ_ΑΝ

! --------------------------------------------------------------

!Δ4. Να διαβάζει ένα επώνυμο και χρησιμοποιώντας τη σειριακή αναζήτηση,
!    σε περίπτωση που το επώνυμο είναι αποθηκευμένο στον πίνακα ΜΕΛΗ,
!    να εμφανίζει το σύνολο των βιβλίων που δανείστηκε στη διάρκεια του
!    έτους. Σε περίπτωση που το επώνυμο δεν είναι αποθηκευμένο στον
!    πίνακα να εμφανίζει το μήνυμα “ΤΟ ΕΠΩΝΥΜΟ ΑΥΤΟ ΔΕΝ ΥΠΑΡΧΕΙ”.
!    Μονάδες 6
!Σημείωση: Δεν απαιτείται κανένας άλλος έλεγχος εγκυρότητας εισαγωγής.
!Δεν υπάρχει συνωνυμία επωνύμων.
  ΓΡΑΨΕ 'Δώσε επώνυμο αναζήτησης: '
  ΔΙΑΒΑΣΕ επώνυμο
  βρέθηκε <- ΨΕΥΔΗΣ
  i <- 1
  ΟΣΟ (i <= ΠΛΗΘΟΣ) ΚΑΙ (βρέθηκε = ΨΕΥΔΗΣ) ΕΠΑΝΑΛΑΒΕ
    ΑΝ επώνυμο = ΜΕΛΗ[i] ΤΟΤΕ
      βρέθηκε <- ΑΛΗΘΗΣ
    ΑΛΛΙΩΣ
      i <- i + 1
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  
  ΑΝ βρέθηκε = ΑΛΗΘΗΣ ΤΟΤΕ
    ΓΡΑΨΕ 'Σύνολο των βιβλίων που δανείστηκε στη διάρκεια του έτους :', SUM[i] 
  ΑΛΛΙΩΣ
    ΓΡΑΨΕ 'ΤΟ ΕΠΩΝΥΜΟ ΑΥΤΟ ΔΕΝ ΥΠΑΡΧΕΙ'
  ΤΕΛΟΣ_ΑΝ

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ