ΠΡΟΓΡΑΜΜΑ ΒΡΑΔ2007_Θ3
!Μία εταιρεία ασφάλισης οχημάτων καθορίζει το ετήσιο κόστος 
!ασφάλισης ανά τύπο οχήματος (δίκυκλο ή αυτοκίνητο) και κυβισμό, 
! σύμφωνα με τους παρακάτω πίνακες: 
!ΔΙΚΥΚΛΟ 
!Κυβισμός (σε κυβικά εκατοστά)  Κόστος Ασφάλισης (σε ευρώ) 
!        έως και 125                   100 
!        πάνω από 125                   140 
!ΑΥΤΟΚΙΝΗΤΟ 
!Κυβισμός (σε κυβικά εκατοστά)  Κόστος Ασφάλισης (σε ευρώ) 
!         έως και 1400                 400 
!         από 1401 έως και 1800         500 
!         πάνω από 1800                 700 
!Αν η ηλικία του οδηγού είναι από 18 έως και 24 ετών τότε το 
!κόστος της ασφάλισης του οχήματος προσαυξάνεται κατά 10%. 
!Να αναπτύξετε αλγόριθμο, ο οποίος: 
!α. Να διαβάζει την ηλικία ενός οδηγού, τον τύπο του οχήματος 
!και τον κυβισμό του, ελέγχοντας ώστε ο τύπος του οχήματος να 
!είναι «ΔΙΚΥΚΛΟ» ή «ΑΥΤΟΚΙΝΗΤΟ». 
!β. Να υπολογίζει και να εμφανίζει το ετήσιο κόστος ασφάλισης 
!του οχήματος. 
!Σημείωση: Να θεωρήσετε ότι η ηλικία του οδηγού είναι 
!τουλάχιστον 18 ετών. 
  
ΜΕΤΑΒΛΗΤΕΣ 
  ΑΚΕΡΑΙΕΣ: ηλικία, κυβισμός 
  ΧΑΡΑΚΤΗΡΕΣ: τύπος_οχήματος 
  ΠΡΑΓΜΑΤΙΚΕΣ: κόστος_ασφάλισης 

ΑΡΧΗ 
  ΓΡΑΨΕ 'Δώσε την ηλικία ενός οδηγού : '
  ΔΙΑΒΑΣΕ ηλικία 
  ΑΝ ηλικία >= 18 ΤΟΤΕ 
    ΓΡΑΨΕ 'Δώσε κυβισμό οχήματος       : '
    ΔΙΑΒΑΣΕ κυβισμός 
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ 
      ΓΡΑΨΕ 'Δώσε τύπο του οχήματος      : '
      ΔΙΑΒΑΣΕ τύπος_οχήματος 
    ΜΕΧΡΙΣ_ΟΤΟΥ τύπος_οχήματος = 'ΔΙΚΥΚΛΟ'  Η τύπος_οχήματος = 'ΑΥΤΟΚΙΝΗΤΟ'

    ΑΝ τύπος_οχήματος = 'ΔΙΚΥΚΛΟ' ΤΟΤΕ
      ΑΝ κυβισμός <= 125 ΤΟΤΕ 
        κόστος_ασφάλισης <- 100 
      ΑΛΛΙΩΣ 
        κόστος_ασφάλισης <- 140 
      ΤΕΛΟΣ_ΑΝ 
    ΑΛΛΙΩΣ 
      ΑΝ κυβισμός <= 1400 ΤΟΤΕ 
        κόστος_ασφάλισης <- 400 
      ΑΛΛΙΩΣ_ΑΝ κυβισμός <= 1800 ΤΟΤΕ 
        κόστος_ασφάλισης <- 500 
      ΑΛΛΙΩΣ 
        κόστος_ασφάλισης <- 700 
      ΤΕΛΟΣ_ΑΝ 
    ΤΕΛΟΣ_ΑΝ 
    
    ΑΝ ηλικία <= 24 ΤΟΤΕ 
      κόστος_ασφάλισης <- κόστος_ασφάλισης* 1.10 
    ΤΕΛΟΣ_ΑΝ 
    
    ΓΡΑΨΕ 'Ετήσιο κόστος ασφάλισης οχήματος : ', κόστος_ασφάλισης
  ΑΛΛΙΩΣ 
    ΓΡΑΨΕ 'Η ηλικία πρέπει να είναι τουλάχιστον 18 ετών' 
  ΤΕΛΟΣ_ΑΝ 
  
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ