2ο ΓΕΛ Γέρακα - Λύσεις Πανελλαδικών ΑΕΠΠ

e-ΜΑΘΗΜΑΤΑ
Ανάπτυξη Εφαρμογών σε Προγραμματιστικό περιβάλλον
Λύσεις ασκήσεων Πανελλαδικών Εξετάσεων

!ΕΠΑΝΑΛΗΠΤΙΚΕΣ ΠΑΝΕΛΛΑΔΙΚΕΣ ΕΞΕΤΑΣΕΙΣ


!ΕΙΣΑΓΩΓΙΚΕΣ ΕΞΕΤΑΣΕΙΣ

!ΤΕΚΝΩΝ ΕΛΛΗΝΩΝ ΤΟΥ ΕΞΩΤΕΡΙΚΟΥ

!ΚΑΙ ΤΕΚΝΩΝ ΕΛΛΗΝΩΝ ΥΠΑΛΛΗΛΩΝ ΠΟΥ ΥΠΗΡΕΤΟΥΝ ΣΤΟ ΕΞΩΤΕΡΙΚΟ

!ΤΕΤΑΡΤΗ 11 ΣΕΠΤΕΜΒΡΙΟΥ 2024

!

!


ΠΡΟΓΡΑΜΜΑ ΘΕΜΑ_Γ_2024_ΟΜΟΓΕΝΩΝ

!ΘΕΜΑ Γ

!Ένα πρατήριο καυσίμων διαθέτει 3 τύπους καυσίμου, βενζίνη, πετρέλαιο και

!υγραέριο, με τιμή 1.80 /lt, 1.50 /lt και 1.30 /lt αντίστοιχα.

!Να αναπτύξετε πρόγραμμα σε ΓΛΩΣΣΑ, το οποίο:

!Γ1. α) Να περιλαμβάνει κατάλληλο τμήμα δηλώσεων (μονάδες 2).

!β) Να διαβάζει τη διαθέσιμη ποσότητα σε λίτρα του κάθε τύπου καυσίμου

!που υπάρχει αρχικά στο πρατήριο (μονάδες 2).

!Μονάδες 4

!Για κάθε όχημα που προσέρχεται στο πρατήριο:

!Γ2. Να διαβάζει τον τύπο καυσίμου, «Β» για βενζίνη, «Π» για πετρέλαιο και «Υ»

!για υγραέριο. Να γίνει έλεγχος εγκυρότητας με κατάλληλο μήνυμα λάθους.

!Μονάδες 4

!Γ3. α) Να διαβάζει το χρηματικό ποσό που επιθυμεί να πληρώσει ο οδηγός του

!οχήματος (χωρίς έλεγχο εγκυρότητας) και να υπολογίζει την ποσότητα

!του αντίστοιχου καυσίμου σε λίτρα. (μονάδες 2)

!β) Στην περίπτωση που η διαθέσιμη ποσότητα καυσίμου στο πρατήριο

!είναι:

!- μικρότερη της ζητούμενης, τότε να προμηθεύεται το όχημα με τη

!διαθέσιμη ποσότητα του πρατηρίου,

!- μεγαλύτερη ή ίση της ζητούμενης, τότε να προμηθεύεται το όχημα με

!τη ζητούμενη ποσότητα (μονάδες 6).

!γ) Η επαναληπτική διαδικασία τερματίζεται όταν ένα από τα 3 είδη καυσίμου

!εξαντληθεί (μονάδες 3).

!Μονάδες 11

!Γ4. Μετά το τέλος της επαναληπτικής διαδικασίας να εμφανίζονται:

!α) Τα συνολικά έσοδα του πρατηρίου (μονάδες 2).

!β) Τα λίτρα που έχουν απομείνει από κάθε τύπο καυσίμου στο πρατήριο

!(μονάδες 2).

!γ) Ο τύπος καυσίμου, από τον οποίο προμηθεύτηκαν τα περισσότερα

!οχήματα. Να θεωρήσετε ότι είναι μοναδικός (μονάδες 2).

!Μονάδες 6

!Παρατηρήσεις:

!α) Όλες οι αρχικές ποσότητες των καυσίμων στο πρατήριο είναι θετικοί αριθμοί

!και δεν απαιτείται έλεγχος εγκυρότητας.

!β) Η χωρητικότητα δεξαμενής καυσίμου του αυτοκινήτου είναι πάντα επαρκής για

!τη ζητούμενη ποσότητα.





ΜΕΤΑΒΛΗΤΕΣ

  ΠΡΑΓΜΑΤΙΚΕΣ: διαθέσιμη_βενζίνη, διαθέσιμο_πετρέλαιο, διαθέσιμο_υγραέριο

  ΠΡΑΓΜΑΤΙΚΕΣ: συνολικά_έσοδα, χρηματικό_ποσό, λίτρα, δόθηκε

  ΧΑΡΑΚΤΗΡΕΣ: τύπος_καυσίμου

  ΑΚΕΡΑΙΕΣ: πλήθος_οχημάτων_βενζίνης, πλήθος_οχημάτων_πετρελαίου, πλήθος_οχημάτων_υγραερίου

ΑΡΧΗ



! αρχικοποιήσεις

  συνολικά_έσοδα <- 0

  πλήθος_οχημάτων_βενζίνης <- 0

  πλήθος_οχημάτων_πετρελαίου <- 0

  πλήθος_οχημάτων_υγραερίου <- 0





!Γ1β

!Να διαβάζει τη διαθέσιμη ποσότητα σε λίτρα του κάθε τύπου καυσίμου

!που υπάρχει αρχικά στο πρατήριο (βενζίνη, πετρέλαιο και υγραέριο)



  ΓΡΑΨΕ 'Δώστε διαθέσιμη ποσότητα βενζίνης   : '

  ΔΙΑΒΑΣΕ διαθέσιμη_βενζίνη

  ΓΡΑΨΕ 'Δώστε διαθέσιμη ποσότητα πετρελαίου : '

  ΔΙΑΒΑΣΕ διαθέσιμο_πετρέλαιο

  ΓΡΑΨΕ 'Δώστε διαθέσιμη ποσότητα υγραερίου  : '

  ΔΙΑΒΑΣΕ διαθέσιμο_υγραέριο





! γ) Η επαναληπτική διαδικασία τερματίζεται όταν ένα από τα 3 είδη καυσίμου εξαντληθεί

  ΟΣΟ διαθέσιμη_βενζίνη > 0 ΚΑΙ διαθέσιμο_πετρέλαιο > 0 ΚΑΙ διαθέσιμο_υγραέριο > 0 ΕΠΑΝΑΛΑΒΕ



!Για κάθε όχημα που προσέρχεται στο πρατήριο:

!Γ2. Να διαβάζει τον τύπο καυσίμου, «Β» για βενζίνη, «Π» για πετρέλαιο και «Υ»

!για υγραέριο. Να γίνει έλεγχος εγκυρότητας με κατάλληλο μήνυμα λάθους.

    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ

      ΓΡΑΨΕ 'Δώστε τύπο καυσίμου (Β/Π/Υ): '

      ΔΙΑΒΑΣΕ τύπος_καυσίμου

      ΑΝ τύπος_καυσίμου <> 'Β' ΚΑΙ τύπος_καυσίμου <> 'Π' ΚΑΙ τύπος_καυσίμου <> 'Υ' ΤΟΤΕ

        ΓΡΑΨΕ 'Λάθος τύπος! Ξαναδώστε'

      ΤΕΛΟΣ_ΑΝ

    ΜΕΧΡΙΣ_ΟΤΟΥ τύπος_καυσίμου = 'Β' Η τύπος_καυσίμου = 'Π' Η τύπος_καυσίμου = 'Υ'



!Γ3. α) Να διαβάζει το χρηματικό ποσό που επιθυμεί να πληρώσει ο οδηγός του

!οχήματος (χωρίς έλεγχο εγκυρότητας) και να υπολογίζει την ποσότητα

!του αντίστοιχου καυσίμου σε λίτρα. (μονάδες 2)

    ΓΡΑΨΕ 'Δώστε χρηματικό ποσό'

    ΔΙΑΒΑΣΕ χρηματικό_ποσό



  ΑΝ τύπος_καυσίμου = 'Β' ΤΟΤΕ

    λίτρα <- χρηματικό_ποσό/ 1.80

  ΑΛΛΙΩΣ_ΑΝ τύπος_καυσίμου = 'Π' ΤΟΤΕ

    λίτρα <- χρηματικό_ποσό/ 1.50

  ΑΛΛΙΩΣ

    λίτρα <- χρηματικό_ποσό/ 1.30



  ΤΕΛΟΣ_ΑΝ





!β) Στην περίπτωση που η διαθέσιμη ποσότητα καυσίμου στο πρατήριο είναι:

!- μικρότερη της ζητούμενης, τότε να προμηθεύεται το όχημα με τη

!διαθέσιμη ποσότητα του πρατηρίου,

!- μεγαλύτερη ή ίση της ζητούμενης, τότε να προμηθεύεται το όχημα με

!τη ζητούμενη ποσότητα (μονάδες 4).

!γ) Η επαναληπτική διαδικασία τερματίζεται όταν ένα από τα 3 είδη καυσίμου

!εξαντληθεί (μονάδες 3).



    ΑΝ τύπος_καυσίμου = 'Β' ΤΟΤΕ

      ΑΝ διαθέσιμη_βενζίνη < λίτρα ΤΟΤΕ

        δόθηκε <- διαθέσιμη_βενζίνη

        διαθέσιμη_βενζίνη <- 0

      ΑΛΛΙΩΣ

        δόθηκε <- λίτρα

        διαθέσιμη_βενζίνη <- διαθέσιμη_βενζίνη - λίτρα

      ΤΕΛΟΣ_ΑΝ

      συνολικά_έσοδα <- συνολικά_έσοδα + δόθηκε* 1.80

      πλήθος_οχημάτων_βενζίνης <- πλήθος_οχημάτων_βενζίνης + 1





    ΑΛΛΙΩΣ_ΑΝ τύπος_καυσίμου = 'Π' ΤΟΤΕ

      ΑΝ διαθέσιμο_πετρέλαιο < λίτρα ΤΟΤΕ

        δόθηκε <- διαθέσιμο_πετρέλαιο

        διαθέσιμο_πετρέλαιο <- 0

      ΑΛΛΙΩΣ

        δόθηκε <- λίτρα

        διαθέσιμο_πετρέλαιο <- διαθέσιμο_πετρέλαιο - λίτρα

      ΤΕΛΟΣ_ΑΝ



      συνολικά_έσοδα <- συνολικά_έσοδα + δόθηκε* 1.50

      πλήθος_οχημάτων_πετρελαίου <- πλήθος_οχημάτων_πετρελαίου + 1



    ΑΛΛΙΩΣ_ΑΝ τύπος_καυσίμου = 'Υ' ΤΟΤΕ

      ΑΝ διαθέσιμο_πετρέλαιο < λίτρα ΤΟΤΕ

        δόθηκε <- διαθέσιμο_υγραέριο

        διαθέσιμο_υγραέριο <- 0

      ΑΛΛΙΩΣ

        δόθηκε <- λίτρα

        διαθέσιμο_υγραέριο <- διαθέσιμο_υγραέριο - λίτρα

      ΤΕΛΟΣ_ΑΝ

      συνολικά_έσοδα <- συνολικά_έσοδα + δόθηκε* 1.30

      πλήθος_οχημάτων_υγραερίου <- πλήθος_οχημάτων_υγραερίου + 1



    ΤΕΛΟΣ_ΑΝ





  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ



!Γ4. Μετά το τέλος της επαναληπτικής διαδικασίας να εμφανίζονται:

!α) Τα συνολικά έσοδα του πρατηρίου.

!β) Τα λίτρα που έχουν απομείνει από κάθε τύπο καυσίμου στο πρατήριο

!γ) Ο τύπος καυσίμου, από τον οποίο προμηθεύτηκαν τα περισσότερα

!οχήματα. Να θεωρήσετε ότι είναι μοναδικός





  ΓΡΑΨΕ 'Συνολικά έσοδα του πρατηρίου: ', συνολικά_έσοδα



  ΓΡΑΨΕ 'Απομένουσα ποσότητα βενζίνης   : ', διαθέσιμη_βενζίνη

  ΓΡΑΨΕ 'Απομένουσα ποσότητα πετρελαίου : ', διαθέσιμο_πετρέλαιο

  ΓΡΑΨΕ 'Απομένουσα ποσότητα υγραερίου  : ', διαθέσιμο_υγραέριο



  ΑΝ πλήθος_οχημάτων_βενζίνης >= πλήθος_οχημάτων_πετρελαίου ΚΑΙ

    & πλήθος_οχημάτων_βενζίνης >= πλήθος_οχημάτων_υγραερίου ΤΟΤΕ

    ΓΡΑΨΕ 'Τύπος καυσίμου περισσότερων οχημάτων: ΒΕΝΖΙΝΗ'

  ΑΛΛΙΩΣ_ΑΝ πλήθος_οχημάτων_πετρελαίου >= πλήθος_οχημάτων_βενζίνης ΚΑΙ

    & πλήθος_οχημάτων_πετρελαίου >= πλήθος_οχημάτων_υγραερίου ΤΟΤΕ

    ΓΡΑΨΕ 'Τύπος καυσίμου περισσότερων οχημάτων: ΠΕΤΡΕΛΑΙΟ'

  ΑΛΛΙΩΣ

    ΓΡΑΨΕ 'Τύπος καυσίμου περισσότερων οχημάτων: ΥΓΡΑΕΡΙΟ'

  ΤΕΛΟΣ_ΑΝ



ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ