2ο ΓΕΛ Γέρακα - Λύσεις Πανελλαδικών ΑΕΠΠ

e-ΜΑΘΗΜΑΤΑ
Ανάπτυξη Εφαρμογών σε Προγραμματιστικό περιβάλλον
Λύσεις ασκήσεων Πανελλαδικών Εξετάσεων

!ΕΠΑΝΑΛΗΠΤΙΚΕΣ ΠΑΝΕΛΛΑΔΙΚΕΣ ΕΞΕΤΑΣΕΙΣ

!ΗΜΕΡΗΣΙΩΝ KAI ΕΣΠΕΡΙΝΩΝ ΓΕΝΙΚΩΝ ΛΥΚΕΙΩΝ

!ΔΕΥΤΕΡΑ 12 ΣΕΠΤΕΜΒΡΙΟΥ 2022



!Α4

! Δίνεται η ΣΥΝΑΡΤΗΣΗ ΠΑΡ που καλείται από το παρακάτω τμήμα προγράμματος:

!α. Να ξαναγράψετε το τμήμα προγράμματος, ώστε να επιτελεί την ίδια λειτουργία,

!   καλώντας ΔΙΑΔΙΚΑΣΙΑ Δ1 αντί της ΣΥΝΑΡΤΗΣΗΣ ΠΑΡ. (μονάδες 3)

!β. Να κατασκευάσετε την ΔΙΑΔΙΚΑΣΙΑ Δ1, ώστε να επιτελεί την ίδια λειτουργία

!   με τη ΣΥΝΑΡΤΗΣΗ ΠΑΡ. (μονάδες 9)

! ΣΗΜΕΙΩΣΗ: Το τμήμα προγράμματος που θα κατασκευάσετε θα πρέπει,

! με τη χρήση της ΔΙΑΔΙΚΑΣΙΑΣ, για τις ίδιες τιμές εισόδου να εμφανίζει

! τις ίδιες τιμές εξόδου με το τμήμα προγράμματος και τη χρήση της συνάρτησης

! που δόθηκαν.





ΠΡΟΓΡΑΜΜΑ Επαναληπτικές2022_Α4

ΜΕΤΑΒΛΗΤΕΣ

  ΑΚΕΡΑΙΕΣ: Α, Β

  ΑΚΕΡΑΙΕΣ: Γ

ΑΡΧΗ



  ΔΙΑΒΑΣΕ Α, Β

  ΓΡΑΨΕ ΠΑΡ(Α, Β) 

  ΓΡΑΨΕ Α, Β



!-----------------



  ΔΙΑΒΑΣΕ Α, Β



  ΚΑΛΕΣΕ Δ1 (Α, Β, Γ) 

  ΓΡΑΨΕ Γ



  ΓΡΑΨΕ Α, Β



! Η συνάρτηση επέστεφε μία ακέραια τιμή, την οποία εκτύπωνε το κύριο πρόγραμμα

! με την εντολή ΓΡΑΨΕ.

! Για τη μετατροπή θα καλέσουμε τη διαδικασία Δ1 με μία επιπλέον παράμετρο

! την οποία θα εκτυπώσουμε.

! Σημείωση: Αν βάζαμε ΓΡΑΨΕ Α, Β, Γ θα είχαμε μία γραμμή εκτύπωσης και όχι δύο,

! όπως στο αρχικό της εκφώνησης.

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ







ΣΥΝΑΡΤΗΣΗ ΠΑΡ(Χ, Υ): ΑΚΕΡΑΙΑ

ΜΕΤΑΒΛΗΤΕΣ

  ΑΚΕΡΑΙΕΣ: Χ, Υ, Ζ

ΑΡΧΗ

  Ζ <- 0

  ΟΣΟ Χ > 0 ΕΠΑΝΑΛΑΒΕ

    ΑΝ Χ mod 2 = 1 ΤΟΤΕ

      Ζ <- Ζ + Υ

    ΤΕΛΟΣ_ΑΝ

    Χ <- Χ div 2

    Υ <- Υ*2

  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΠΑΡ <- Ζ

ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ



ΔΙΑΔΙΚΑΣΙΑ Δ1 (Χ, Υ, Α) 

ΜΕΤΑΒΛΗΤΕΣ

  ΑΚΕΡΑΙΕΣ: Χ, Υ, Ζ

  ΑΚΕΡΑΙΕΣ: Α, tempX, tempY

ΑΡΧΗ





! επειδή οι τιμές των ματεβλητών/παραμέτρων Χ,Υ μεταβάλλονται

! κατά τον υπολογισμό της τιμής της συνάρτησης, θα τις αποθηκεύσουμε

! σε δύο προσωρινές μεταβλητές



  tempX <- Χ

  tempY <- Υ



! αφήνουμε τον κώδικα της συνάρτησης όπως ήταν.



! ------------------

  Ζ <- 0

  ΟΣΟ Χ > 0 ΕΠΑΝΑΛΑΒΕ

    ΑΝ Χ mod 2 = 1 ΤΟΤΕ

      Ζ <- Ζ + Υ

    ΤΕΛΟΣ_ΑΝ

    Χ <- Χ div 2

    Υ <- Υ*2

  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

!-----------------





  Α <- Ζ

! ενημερώνουμε την μεταβλητή που πρέπει να επιστρέψουμε

! με ότι τιμή επέστρεφε η συνάρτηση



! επαναφέρουμε στις μεταβλητές Χ, Υ στις αρχικές τους τιμές ,

! όπως τις είχαμε σώσει, επειδή η συνάρτηση επιστρέφει μόνο την τιμή της





  Χ <- tempX

  Υ <- tempY



ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ