e-ΜΑΘΗΜΑΤΑ
Ανάπτυξη Εφαρμογών σε Προγραμματιστικό περιβάλλον

Λύσεις ασκήσεων από τον Οδηγό Μελέτης Μαθητών


ΠΡΟΓΡΑΜΜΑ τράπεζα
! ΑΕΠΠ - Οδηγός Μελέτης Μαθητή
! Μη λυμένες ασκήσεις 4.10.8
!
! 8. Μια τράπεζα διαχειρίζεται τους λογαριασμούς πελατών της χρησιμοποιώντας
!    2 πίνακες. Τον πίνακα ΟΝΟΜΑ που περιέχει τα ονοματεπώνυμα των πελατών της
!    και τον πίνακα ΛΟΓΑΡΙΑΣΜΟΣ που περιέχει τα υπόλοιπα των λογαριασμών τους.
! Να γραφεί πρόγραμμα σε "ΓΛΩΣΣΑ", το οποίο να:
! 1) Διαβάζει τον αριθμό των πελατών της τράπεζας, ελέγχοντας ότι είναι
!    θετικός αριθμός με ανώτατο όριο 10.000.000. Στη περίπτωση που δοθεί
!    λάθος νούμερο, να τυπώνεται το μήνυμα " Μη αποδεκτός αριθμός... Ξαναπροσπαθήστε...."
!    και να επαναλαμβάνεται η διαδικασία μέχρι αποδεκτής τιμής.
! 2) Διαβάζει τα Ονοματεπώνυμο και υπόλοιπο λογαριασμού ΓΙΑ κάθε πελάτη της
!    τράπεζας, καταχωρώντας τα αντίστοιχα στους πίνακες ΟΝΟΜΑ και ΛΟΓΑΡΙΑΣΜΟΣ.
! 3) Διαβάζει το ονοματεπώνυμο, την προτίμηση ενός πελάτη για κατάθεση ή ανάληψη
!    χρημάτων ( Κ= κατάθεση, Α= ανάληψη) καθώς και το ποσό.
!    Η διαδικασία αυτή επαναλαμβάνεται μέχρι να δοθεί ως ονοματεπώνυμο πελάτη η λέξη "ΤΕΛΟΣ".
! 4) Για κάθε πελάτη που διαβάζει να κάνει τα εξής:
!     a. Να ελέγχει, στην περίπτωση ανάληψης, αν αυτή μπορεί να γίνει
!        και να εμφανίζει το μήνυμα "Δεν επαρκεί το υπόλοιπό σας...."
!        στην περίπτωση που δεν είναι εφικτή.
!     b. Σε κάθε περίπτωση (κατάθεση ή ανάληψη) να ενημερώνεται ο πίνακας
!        με τον λογαριασμό του πελάτη ανάλογα σε κάθε περίπτωση.
!     c. Να εμφανίζει το νέο υπόλοιπο λογαριασμού.
! 5) Να εμφανίζει το σύνολο των καταθέσεων που έγιναν.

ΣΤΑΘΕΡΕΣ
  max = 1000
ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ: ΟΝΟΜΑ[max], όνομα_πελάτη, προτίμηση
  ΠΡΑΓΜΑΤΙΚΕΣ: ΛΟΓΑΡΙΑΣΜΟΣ[max], σύνολο_καταθέσεων, ποσό
  ΑΚΕΡΑΙΕΣ: i, αριθμός_πελατών, θέση

ΑΡΧΗ
! 1. Διάβασμα αριθμού  πελατών της τράπεζας
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ 'Δώστε αριθμό  πελατών της τράπεζας'
    ΔΙΑΒΑΣΕ αριθμός_πελατών
    ΑΝ αριθμός_πελατών < 0 Η αριθμός_πελατών > max ΤΟΤΕ
      ΓΡΑΨΕ 'Μη αποδεκτός αριθμός... Ξαναπροσπαθήστε....'
    ΤΕΛΟΣ_ΑΝ
  ΜΕΧΡΙΣ_ΟΤΟΥ αριθμός_πελατών > 0 ΚΑΙ αριθμός_πελατών <= max

! 2. Διάβασμα σε Ονοματεπώνυμο και υπόλοιπο λογαριασμών
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ αριθμός_πελατών
    ΓΡΑΨΕ i, 'ος πελάτης:'
    ΓΡΑΨΕ 'Δώστε όνομα           : '
    ΔΙΑΒΑΣΕ ΟΝΟΜΑ[i] 
    ΓΡΑΨΕ 'Δώστε ποσό λογαριασμού: '
    ΔΙΑΒΑΣΕ ΛΟΓΑΡΙΑΣΜΟΣ[i] 
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ


! 3. Κινήσεις λογαρισμού πελατών

  σύνολο_καταθέσεων <- 0

  ΓΡΑΨΕ 'Δώστε όνομα πελάτη'
  ΔΙΑΒΑΣΕ όνομα_πελάτη
  ΟΣΟ όνομα_πελάτη <> 'ΤΕΛΟΣ' ΕΠΑΝΑΛΑΒΕ
    θέση <- 0
    i <- 1
    ΟΣΟ i <= αριθμός_πελατών ΚΑΙ θέση = 0 ΕΠΑΝΑΛΑΒΕ
      ΑΝ ΟΝΟΜΑ[i] = όνομα_πελάτη ΤΟΤΕ
        θέση <- i
      ΑΛΛΙΩΣ
        i <- i + 1
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

    ΑΝ θέση <> 0 ΤΟΤΕ

! Διάβασμα προτίμησης και ποσού
      ΓΡΑΨΕ 'Δώστε προτίμηση ( Κ= κατάθεση, Α= ανάληψη): '
      ΔΙΑΒΑΣΕ προτίμηση

      ΑΝ προτίμηση = 'Α' ΤΟΤΕ
        ΓΡΑΨΕ 'Δώστε ποσό ανάληψης: '
        ΔΙΑΒΑΣΕ ποσό
        ΑΝ ποσό > ΛΟΓΑΡΙΑΣΜΟΣ[θέση] ΤΟΤΕ
          ΓΡΑΨΕ 'Δεν επαρκεί το υπόλοιπό σας....'
        ΑΛΛΙΩΣ
          ΛΟΓΑΡΙΑΣΜΟΣ[θέση] <- ΛΟΓΑΡΙΑΣΜΟΣ[θέση] - ποσό
          ΓΡΑΨΕ 'Νέο υπόλοιπο:', ΛΟΓΑΡΙΑΣΜΟΣ[θέση] 
        ΤΕΛΟΣ_ΑΝ

      ΑΛΛΙΩΣ_ΑΝ προτίμηση = 'Κ' ΤΟΤΕ

        ΓΡΑΨΕ 'Δώστε ποσό κατάθεσης: '
        ΔΙΑΒΑΣΕ ποσό
        ΛΟΓΑΡΙΑΣΜΟΣ[θέση] <- ΛΟΓΑΡΙΑΣΜΟΣ[θέση] + ποσό
        σύνολο_καταθέσεων <- σύνολο_καταθέσεων + ποσό
        ΓΡΑΨΕ 'Νέο υπόλοιπο:', ΛΟΓΑΡΙΑΣΜΟΣ[θέση] 

      ΑΛΛΙΩΣ
        ΓΡΑΨΕ 'Λάθος προτίμηση'
      ΤΕΛΟΣ_ΑΝ
    ΑΛΛΙΩΣ
      ΓΡΑΨΕ 'Δεν βρέθηκε τέτοιος πελάτης'
    ΤΕΛΟΣ_ΑΝ

    ΓΡΑΨΕ 'Δώστε όνομα επόμενου πελάτη'
    ΔΙΑΒΑΣΕ όνομα_πελάτη
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΡΑΨΕ 'Σύνολο των καταθέσεων που έγιναν: ', σύνολο_καταθέσεων
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ

 

© 2017 - 2ο Γενικό Λύκειο Γέρακα - Βασίλειος Αναστόπουλος